package Top;

import Connectable::*;
import GetPut::*;
import ClientServer::*;

import Blinky::*;
import PackUnpack::*;
import UART::*;
import VRAM::*;

module mkUARTDebugger(Integer clock_frequency, Integer uart_bitrate, VRAMServer mem, UART_PHY ifc);
   UART uart <- mkUART(clock_frequency, uart_bitrate);
   disableFlowControl(uart); // Can't do hardware flow control on ULX3S

   Server#(Bit#(8), VRAMRequest) decode <- mkUnpacker();
   Server#(VRAMResponse, Bit#(8)) encode <- mkPacker();

   mkConnection(uart.receive, decode.request);
   mkConnection(decode.response, mem.request);
   mkConnection(mem.response, encode.request);
   mkConnection(encode.response, uart.send);

   return uart.phy;
endmodule

interface Top;
   (* always_enabled,prefix="debug" *)
   method Action debugger_rx_in((* port="serial_in" *) bit b);
   (* always_ready,result="debug_serial_out" *)
   method bit debugger_tx_out();

   (* always_ready *)
   method Bool led();
endinterface

(* synthesize *)
module mkTop(Top);
   ////////////
   // Memory
   VRAM mem <- mkVRAM(4);

   ////////////
   // Debugging
   let debugger <- mkUARTDebugger(25_000_000, 115_200, mem.debugger);
   let blinky <- mkBlinky(25_000_000);

   ////////////
   // External interface
   method debugger_rx_in = debugger.rx_in;
   method debugger_tx_out = debugger.tx_out;

   method led = blinky.led_on;
endmodule

endpackage